Vb.Net İle MYSQL Veritabanına Bağlantı Kurmak

Bu yazımda size Vb.Net ile Mysql veritabanına bağlantının nasıl kurulacağını anlatacağım. Mysql ile ilk defa program yazacaksanız burada ki videolu kurulumu izlemenizi öneririm.

Veritabanımızı, performanslı kullanabilmek için, veritabanını ayrı bir makinede tutarız. Makinenin görevi sadece veritabanını çalıştırmak ve performanslı bir şekilde kullanıcıya bu bilgileri aktarmaktır.Çalışmalarınızda veritabanını farklı bir yerde tutmanızı öneririm.

Örneğin ben, yeni bir projeye başlamadan önce, Vmware üzerinde temiz kurulum Windows Server 2003 makinemi, projeye yapmayı düşündüğüm veritabanını kurup,  performans ayarlarını yaparım.

Eğer ilk defa Mysql ile bir bağlantı kuracaksanız bazı sorunlar yaşayabilirsiniz.  (veritabanını ayrı bir bilgisayarda tutarsanız)

Bunlardan birincisi güvenlik izinleridir. Mysql oluşturduğunuz ana kullanıcının kurulu bilgisayar dışından girmenize izin vermez.  Ana kullanıcınız ne kadar yüksek izinlere sahip olsa da dışardan gelen kullanıcılara bağlanması için özel ayarlamalar yapmamız gerekir. Kurulum videosunun sonuna doğru bu konu hakkında kısa bir açıklama yapmıştım. (Video da bayağa yerde tıkanmışım. Tek seferde video çekmenin zararları 🙁 )

Mysql veritabanı framework üzerinde sınıflara sahip bir veritabanı değildir. Yani Mysql’in bağlantı ve sorgulama işlemleri için Mysql tarafından yazılmış olan Connector denilen bağlantı aracını kullanacağız.

Bağlantı aracını aşağıda ki linkten indirip kurabilirsiniz.

Mysql Connector Net (3311)

• Connector (bundan sonra bağlantı aracı olarak yazılacak) aracımızı da yükledikten sonra Visual Studio da bu bağlantı aracını eklememiz gerekiyor. Yeni bir proje oluşturduktan sonra menüden PROJECT ->ADD REFERENCES bölümünden .NET Sekmesinden Mysql.Data seçip ekliyoruz.

VisualStudio'da Mysql Bağlantı Aracını Projeye Dahil Etme

• Mysql için bağlantı dizelerini aşağıda yer verdim. Bunlardan birini seçip baglanti_dizi içine yazmanız yeterlidir. Hepsinin kullanım amaçları hepsi aynıdır. İhtiyacınız olan birisini kullanabilirsiniz.

 Server=myServerAddress;Database=myDataBase;Uid=myUsername;Pwd=myPassword; 

 Server=myServerAddress;Database=myDataBase;Uid=myUsername;Pwd=myPassword;Connection Timeout=5; 

 Server=myServerAddress;Database=myDataBase;Uid=myUsername;Pwd=myPassword;Port=3306; 

 Server=myServerAddress;Database=myDataBase;Uid=myUsername;Pwd=myPassword;CharSet=UTF8; 

• Server: Mysql sunucunun bulunduğu adrestir. Örn : ehocam.com, 192.168.2.21, 88.227.179.231, localhost, 127.0.0.1
• Database: Mysql sunucusunda, belirtmiş olduğunuz adresteki, kullanmak istediğiniz veritabanının adıdır.
• Uid : Seçtiğiniz veritabanının erişim yetkisine sahip kullanıcının, kullanıcı adıdır.
• Pwd : Seçtiğiniz veritabanının erişim yetkisine sahip kullanıcının, şifresidir.
• Connection Timeout : Belirlediğiniz saniye kadar bağlantı kurmaya çalışacaktır. Eğer belirlediğiniz saniye içinde bağlantı kuramazsa hata verecektir.
• Port : Mysql sunucusunun hizmet verdiği port 3306 (standart) dışında ise  buraya hizmet verdiği portu yazabilirsiniz.
• Charset : Mysql sunucusu üzerinde, bağlanacağınız veritabanının, hangi karakter seti üzerinde işlem yapmasını istiyorsanız, bu değere karakter setini yazmalısınız.

Yukarıda yazdıklarım mysql bağlantısı için kullanılan özelliklerdir. Bağlantı aracını yükledikten sonra framework kütüphanesine MySqlConnectionStringBuilder adlı bir sınıf ekleniyor.  Tabi bu sınıfları kullanabilmek için MySql.Data.MySqlClient formumuza dahil ediyoruz.

Imports MySql.Data.MySqlClient

MySqlConnectionStringBuilder sınıfı yukarıda ki bağlantı dizisini oluşturmamıza yarıyor. Kullanımı aşağıdadır.

Dim baglanti_dizisi As New MySqlConnectionStringBuilder
baglanti_dizisi.Server = "192.168.153.132"
'baglanti_dizisi.Database = "ogrenci"
baglanti_dizisi.UserID = "cagdaskarademir"
baglanti_dizisi.Password = "123456"

Bağlantı kurmak için ise aşağıda ki mysql bağlantısı değişkenimi kullanıyorum.

 Public mysql_baglanti As New MySqlConnection 

Bağlanmak için ise;

        mysql_baglanti.ConnectionString = baglanti_dizisi.ToString

        Try
            mysql_baglanti.Open() 'Bağlantımı Açıyorum
        Catch ex As MySqlException 'Hata sınıfı olarak Mysql'in hata sınıfını kullanıyorum.
            MessageBox.Show(ex.Message, "Hata Kodu : " & ex.Number.ToString, MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            mysql_baglanti.Close() 'Performans açısından açtığım bağlantıyı kapatıyorum.
        End Try

Kısacası şimdiye kadar bağlantımızın nasıl kurulduğunu gördük. Şu zamana kadar kodların tümünü aşağıda bulabilirsiniz. Ama bağlantımızın durumunu, Mysql sınıfı içindeki bir fonksiyon aracılığı ile kolayca yapabiliyoruz. Önce kodlara gözatın hemen ardından Mysql sınıfının StateChange olayına gözatalım.

Imports MySql.Data.MySqlClient 'Kütüphaneyi dahil ediyoruz.

Public Class Form1

    Public baglanti_dizisi As New MySqlConnectionStringBuilder
    Public mysql_baglanti As New MySqlConnection

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        baglanti_dizisi.Server = "192.168.153.132" 'Sunucu Ip adresini giriyorum
        baglanti_dizisi.Database = "ogrenci" 'Veritabanı adını giriyorum
        baglanti_dizisi.UserID = "cagdaskarademir" 'Kullanıcı adımı giriyorum
        baglanti_dizisi.Password = "123456" 'şifremi giriyorum

        mysql_baglanti.ConnectionString = baglanti_dizisi.ToString

        Try
            mysql_baglanti.Open() 'Bağlantımı açıyorum
        Catch ex As MySqlException 'MysqlExpection sınıfını kullanarak mysql hata verirse hataları ayrıntılı alabiliyorum
            MessageBox.Show(ex.Message, "Hata Kodu : " & ex.Number.ToString, MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            mysql_baglanti.Close() 'Bağlantımı kapatıyorum
        End Try
    End Sub

End Class

mysql_baglanti.Open() komutunu verdikten sonra, baglanti_dizisi‘nde yer alan bilgiler doğrultusunda işlemler yapılmaya başlanıyor. Bu aşamada, önce sunucuyu araması,bağlanması, işlem yapması ve en sonunda bağlantının kapanması gerekir.

Biz MySqlConnection sınıfında bağlantının durumunu State özelliği ile yapabiliyoruz. Fakat projelerimizde mysql bağlantısının anlık değişimlerini almak isteyebiliriz.

Örneğin bağlantı kurulumu yaparken StatusStrip‘de ayrı bir resim gösterip, Bağlantı kurulduğunda veya koptuğunda ayrı bir resim göstermek isteyebiliriz.

Bu gibi bir ihtiyaçta, Mysql sınıfında yer alan StateChange olayını handle edip kullanabiliriz.

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        AddHandler mysql_baglanti.StateChange, AddressOf mysql_baglanti_durumu 'StateChange olayını mysql_baglanti_durum fonksiyonuna yönlendiriyorum.
    End Sub

    Private Sub mysql_baglanti_durumu(ByVal sender As Object, ByVal e As StateChangeEventArgs)
        MessageBox.Show(e.CurrentState.ToString) 'Bağlantı değişiminde hemen bana haber vermesini sağlıyorum.
    End Sub

Şimdi de bu yaptıklarımızı bir projede kullanalım.

Aşağıdaki gibi bir görüntü oluşturun.

• 2 Tane Buton
• 3 Tane Label
  • Label1.text=” Server”
  • Label2.text= “UserID”
  • Label3 .text=”Password”
• 3 Tane Textbox
  • txtServer
  • txtUserId
  • txtPassword
• 1 StatusStrip
  • 2 tane ToolStripStatusLabel
    • ToolStripStatusLabel1.text=”Mysql Bağlantı Durumu”
    • ToolStripStatusLabel2.text=””  –> Bağlantı değişimlerinde resimler burada çıkacak
• 1 ToolStrip
  • HelpToolStripButton.text = “Yardım”

Mysql Bağlantısı Örneği Form Önizleme

Imports MySql.Data.MySqlClient

Public Class Form1

    Public baglanti_dizisi As New MySqlConnectionStringBuilder
    Public mysql_baglanti As New MySqlConnection

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        baglanti_dizisi.Server = txtServer.Text 'İlk kutumun adı
        'baglanti_dizisi.Database = "ogrenci" 'Projenin amacına göre girilmedi. Girilmesi şart değil.
        baglanti_dizisi.UserID = txtUserID.Text 'İkinci kutumun adı
        baglanti_dizisi.Password = txtPassWord.Text 'Üçüncü kutumun adı

        mysql_baglanti.ConnectionString = baglanti_dizisi.ToString

        Try
            mysql_baglanti.Open()
        Catch ex As MySqlException
            MessageBox.Show(ex.Message, "Hata Kodu : " & ex.Number.ToString, MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        AddHandler mysql_baglanti.StateChange, AddressOf mysql_baglanti_durumu
    End Sub

    Private Sub mysql_baglanti_durumu(ByVal sender As Object, ByVal e As StateChangeEventArgs)
        If e.CurrentState = ConnectionState.Connecting Then
            Me.ToolStripStatusLabel2.Image = My.Resources.baglaniyor
        ElseIf e.CurrentState = ConnectionState.Open Then
            Me.ToolStripStatusLabel2.Image = My.Resources.baglandi
        ElseIf e.CurrentState = ConnectionState.Closed Then
            Me.ToolStripStatusLabel2.Image = My.Resources.baglanti_sonlandi
        End If
    End Sub

    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        mysql_baglanti.Close()
    End Sub

    Private Sub HelpToolStripButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles HelpToolStripButton.Click
        System.Diagnostics.Process.Start("http://www.ehocam.com/?p=842")
    End Sub
End Class

Projenin demosuna ve kaynak kodlarına aşağıdan ulaşabilirsiniz.

• {title} ({hits})
• Mysql Baglantisi Örnegi #1# Kaynak Kodlari (VS2010) (2261)